WeMos D1 mini (esp8266): SPIFFS FileSystem integrato – Parte 2

SPI Flash File System (SPIFFS)

File system flash per interfaccia periferica seriale, o SPIFFS in breve. È un file system leggero per i microcontrollori con un chip flash SPI. Il chip flash integrato nell’ESP8266 offre molto spazio per i file. 
Il WeMos D1 mini ha 4 Mb di flash e ne puoi utilizzare fino a 3 per i tuoi files. 
Lo SPIFFS ti consente di accedere alla memoria flash come se fosse un normale file system come quello sul tuo computer (ma ovviamente molto più semplice): puoi leggere e scrivere file, creare cartelle ecc.

In questa memoria flash l’ESP memorizza il programma. Insieme al programma è possibile memorizzare i nostri file. Il limite di questa memoria è che ha solo 10000 (diecimila) cicli di scrittura.

Una cosa importante da sottolineare è che lo SPIFFS su esp8266 non supporta le directory, e la dimensione massima del nome dei file è 32 caratteri.

Aggiungere file dall’IDE Arduino su SPIFFS

Questa operazione senza estensione per l’IDE di Arduino non è così semplice, ma qui andremo a vedere il modo più semplice.

Per prima cosa devi scaricare il plug-in per l’Arduino IDE qui la versione 0.5.0 è questa .

Quindi devi trovare la tua cartella dei Shetckbook, se non sai dove è dislocata puoi andare su File --> Preferences, in quella schermata puoi trovare nella parte superiore della finestra lo Sketchbook location.

Ora devi creare (se non esiste) la cartella tools\ESP8266FS\toole aggiungere esp8266fs.jar lì il file jar.

Ora riavvia l’IDE e nel menu Tools  troverai una nuova riga ESP8266 Sketch Data Upload.

Sull’Arduino IDE fai Ctrl+Kper aprire un Esplora risorse nella directory dello sketch. 
Crea una directory denominata datadove andrai ad inserire i dati che desideri caricare.

Imposta la dimensione dello SPIFFS Tools --> Flash size e imposta la dimensione del filesystem.

Carica il tuo sketch e fai clic su ESP8266 Sketch Data Upload.

Ora vai allo sketch di esempio per verificare se tutto è OK.

Comandi

Ci sono alcuni comandi standard che puoi usare con questo filesystem

SPIFFS.begin ()
Questo metodo monta il file system SPIFFS e deve essere chiamato prima di utilizzare qualsiasi altra API FS. Restituisce vero se il file system è stato montato correttamente, altrimenti falso.

SPIFFS.format ()
Formatta il file system. Restituisce vero se la formattazione ha avuto esito positivo.

SPIFFS.open (percorso, modalità)
Apre un file. il percorso dovrebbe essere un percorso assoluto che inizia con una barra (ad es. /dir/filename.txt). modalità è una stringa che specifica la modalità di accesso. Può essere uno di “r”, “w”, “a”, “r +”, “w +”, “a +”. Il significato di queste modalità è lo stesso della funzione C fopen. 
Restituisce l’oggetto File. Per verificare se il file è stato aperto correttamente, utilizzare l’operatore booleano.

SPIFFS.exists (percorso)
Restituisce vero se esiste un file con un determinato percorso, altrimenti falso.

SPIFFS.openDir (percorso)
Apre una directory dato il suo percorso assoluto. Restituisce un oggetto Dir.

SPIFFS.remove (percorso) 
elimina un file dato il suo percorso assoluto. Restituisce vero se il file è stato eliminato correttamente.

SPIFFS.rename (pathFrom, pathTo)
Rinomina il file da pathFrom a pathTo. I percorsi devono essere assoluti. Restituisce vero se il file è stato rinominato correttamente.

SPIFFS.info (fs_info)
Riempie la struttura di FSInfo con informazioni sul file system. Restituisce vero ha esito positivo, altrimenti falso.

file.seek (offset, mode)
Questa funzione si comporta come la funzione fseek C. A seconda del valore della modalità, sposta la posizione corrente in un file come segue:

• se mode è SeekSet, la posizione è impostata per compensare i byte dall’inizio.
• se mode è SeekCur, la posizione corrente viene spostata di byte offset.
• se mode è SeekEnd, position è impostato per compensare i byte dalla fine del file.
• Restituisce vero se la posizione è stata impostata correttamente.

file.position ()
Restituisce la posizione corrente all’interno del file, in byte.

file.size ()
Restituisce la dimensione del file, in byte.

file.name ()
Restituisce il nome del file, come const char *.

file.close ()
Chiude il file.

Esempi pratici

Ecco uno sketch per ottenere informazioni e controllare tutti i file nel tuo SPIFFS.

/*
 *  WeMos D1 mini (esp8266)
 *  SPIFFS get info, read dir and show all file uploaded
 *  add a data folder to use with esp8266 data uploader
 *  by Mischianti Renzo <https://mischianti.org>
 *
 *  https://mischianti.org/wemos-d1-mini-esp8266-integrated-spiffs-filesistem-part-2/
 *
 */

#include "Arduino.h"
#include "FS.h"

void setup()
{
	Serial.begin(112500);

	delay(500);

	Serial.println(F("Inizializing FS..."));
	if (SPIFFS.begin()){
		Serial.println(F("done."));
	}else{
		Serial.println(F("fail."));
	}

	// To format all space in SPIFFS
	// SPIFFS.format()

	// Get all information of your SPIFFS
	FSInfo fs_info;
	SPIFFS.info(fs_info);

	Serial.println("File sistem info.");

	Serial.print("Total space:      ");
	Serial.print(fs_info.totalBytes);
	Serial.println("byte");

	Serial.print("Total space used: ");
	Serial.print(fs_info.usedBytes);
	Serial.println("byte");

	Serial.print("Block size:       ");
	Serial.print(fs_info.blockSize);
	Serial.println("byte");

	Serial.print("Page size:        ");
	Serial.print(fs_info.totalBytes);
	Serial.println("byte");

	Serial.print("Max open files:   ");
	Serial.println(fs_info.maxOpenFiles);

	Serial.print("Max path length:  ");
	Serial.println(fs_info.maxPathLength);

	Serial.println();

	// Open dir folder
	Dir dir = SPIFFS.openDir("/");
	// Cycle all the content
	while (dir.next()) {
		// get filename
	    Serial.print(dir.fileName());
        Serial.print(" - ");
        // If element have a size display It else write 0
	    if(dir.fileSize()) {
	        File f = dir.openFile("r");
	        Serial.println(f.size());
	        f.close();
	    }else{
	    	Serial.println("0");
	    }
	}
}

void loop()
{

}

Qui uno sketch con comandi più pratici, scrivi una stringa in un file, leggi tutto il contenuto del file, posizionati sul 9 byte del file e leggi da lì i dati.

/*
 *  WeMos D1 mini (esp8266)
 *  SPIFFS write, read and seek file
 *  by Mischianti Renzo <https://mischianti.org>
 *
 *  https://mischianti.org/wemos-d1-mini-esp8266-integrated-spiffs-filesistem-part-2/
 *
 */
#include "Arduino.h"
#include "FS.h"

void setup()
{
	Serial.begin(112500);

	delay(500);

	Serial.println(F("Inizializing FS..."));
	if (SPIFFS.begin()){
		Serial.println(F("done."));
	}else{
		Serial.println(F("fail."));
	}

	// To remove previous test
	// SPIFFS.remove(F("/testCreate.txt"));

	File testFile = SPIFFS.open(F("/testCreate.txt"), "w");

	if (testFile){
		Serial.println("Write file content!");
		testFile.print("Here the test text!!");

		testFile.close();
	}else{
		Serial.println("Problem on create file!");
	}

	testFile = SPIFFS.open(F("/testCreate.txt"), "r");
	if (testFile){
		Serial.println("Read file content!");
		/**
		 * File derivate from Stream so you can use all Stream method
		 * readBytes, findUntil, parseInt, println etc
		 */
		Serial.println(testFile.readString());
		testFile.close();
	}else{
		Serial.println("Problem on read file!");
	}

	testFile = SPIFFS.open(F("/testCreate.txt"), "r");
	if (testFile){
		/**
		 * mode is SeekSet, position is set to offset bytes from the beginning.
		 * mode is SeekCur, current position is moved by offset bytes.
		 * mode is SeekEnd, position is set to offset bytes from the end of the file.
		 * Returns true if position was set successfully.
		 */
		Serial.println("Position inside the file at 9 byte!");
		testFile.seek(9, SeekSet);

		Serial.println("Read file content!");
		Serial.println(testFile.readString());
		testFile.close();
	}else{
		Serial.println("Problem on read file!");
	}


}

void loop()
{

}

Grazie

1. WeMos D1 mini (esp8266): caratteristiche e configurazione dell’Arduino IDE
2. WeMos D1 mini (esp8266): SPIFFS Filesystem integrato
3. WeMos D1 mini (esp8266): debug sulla seriale secondaria
4. WeMos D1 mini (esp8266), i tre tipi di modalità di sospensione per gestire il risparmio energetico
5. WeMos D1 mini (esp8266): FileSystem integrato LittleFS
6. esp12 esp07 (esp8266): flash, piedinatura, spec e config dell’IDE Arduino

7. Firmware and OTA update
   • Gestione del firmware
     1. esp8266: flash del firmware binario(.bin) compilato e firmato
     2. esp8266: flash del firmware e file system binario (.bin) compilato con strumenti grafici (GUI)
   • Aggiornamenti OTA con Arduino IDE
     1. esp8266 aggiornamenti OTA dall’IDE Arduino: filesystem, firmware firmato e password
   • Aggiornamenti OTA con Web Browser
     1. esp8266 Aggiornamenti OTA da Browser Web: firmware, filesystem e autenticazione
     2. esp8266 Aggiornamenti OTA da Browser Web: firma del firmware e HTTPS (SSL/TLS)
     3. esp8266 aggiornamenti OTA da Browser Web: interfaccia web personalizzata
   • Aggiornamenti OTA automatico da server HTTP
     1. esp8266 auto aggiornamenti OTA del firmware da server remoto
     2. esp8266 auto aggiornamenti OTA del firmware da server con controllo della versione
     3. esp8266 auto aggiornamenti OTA in HTTPS (SSL/TLS) con certificato autofirmato attendibile
   • Aggiornamenti firmware non standard
     1. esp8266 aggiornamenti del firmware e del filesystem da scheda SD
     2. esp8266 aggiornamenti del firmware e del filesystem con client FTP

8. esp32 e esp8266: file system FAT su memoria SPI flash esterna
9. i2c esp8266: how to, rete 5V, 3.3V, velocità e pin personalizzati
10. …